[NLRS] Question on field strength

[Ford Peterson]

Jon asks:

OK, a question a little off topic, but still radio ! Suppose that I had 
a specification for a transmitter that could not exceed a field 
strength of 50mV/m @ 3 meters. How do I translate that spec into input 
power at the transmitting antenna ? For simple sake, lets assume that 
the transmitting antenna is a dipole and this is 900 MHz or so, so that 
3 meters is (close ?) to being far field.

73, W0ZQ


Mr. Wizard answers:

50uV/m @ 3M @ 900MHz is -81.78268 dBm

Now, if you want to know how I got there from here, that will take some
research.  I have an old Basic software utility that I wrote years ago based
on article on Part 15 Parameters published in the March/April 1992 EMC Test
& Design magazine.  It's about 40 lines of code but would be a cake walk to
for you to extract the logic if you are unable to locate a 15 year old trade
journal.

The utility I wrote allows you to enter the frequency of interest, and the
3M field in uV/M, it expounds the input power and the distance in meters and
miles to the field strength in -5dB increments.  It of course assumes any
number of caveats like: clear path, no obstructions, no reflections, etc.

Here is the screen output and basic source code: Amazingly, it still runs on
XP.

Enjoy...

Ford-N0FP

FCC LIMITS:
Frequency =  900  MHz
FCC 3-M FIELD =  50  uv/M           
TRANSMITTER POWER =          0.0000000MW  =         -81.7826800  dBm

Path Loss          D,M             D,FT            D,MI
 30                1.3              4.2           0.001
 35                2.3              7.4           0.001
 40                4.0             13.1           0.002
 45                7.1             23.3           0.004
 50               12.7             41.5           0.008
 55               22.5             73.8           0.014
 60               40.0            131.3           0.025
 65               71.2            233.4           0.044
 70              126.5            415.1           0.079
 75              225.0            738.1           0.140
 80              400.2           1312.6           0.249
 85              711.6           2334.2           0.442
 90             1265.5           4150.8           0.786
 95             2250.4           7381.3           1.398
100             4001.8          13126.0           2.486
105             7116.4          23341.7           4.421




10 CLS
20 '******* Calculates path loss using Part 15 Parameters
30 '*******  Taken from article in March/April 1992 EMC Test & Design
40 INPUT"Print (P) or Screen (S) or File (F) ";PS$
45 IF PS$="F" OR PS$="f" THEN OPEN "FCCLIMIT.TXT" FOR OUTPUT AS #3:GOTO 60
50 IF PS$="P" OR PS$="p" THEN OPEN "lpt1:" FOR OUTPUT AS #3:GOTO 60
55 OPEN "SCRN:" FOR OUTPUT AS #3
60 WIDTH #3,80
100 B=LOG(10)
110 I$="###        #########.#      #########.#     #######.###"
120 J$="  ########.#######"
130 D$="  ########.#######"
135 LOCATE 1,1:PRINT STRING$(40," ")
140 LOCATE 1,1:INPUT "Frequency, MHz ";F
150 LOCATE 1,1:PRINT#3,"Frequency = ";F;" MHz"
160 INPUT "3-M Field by FCC, uV/m ";E#
170 WT=(2.1492E-06)*(E#/F)^2
180 WTD=(10/B)*LOG(WT)
220 LOCATE 2,1:PRINT#3,"FCC 3-M FIELD = ";E#;" uv/M           "
230 PRINT#3,"TRANSMITTER POWER = ";
240 PRINT#3,USING J$;WT;:PRINT#3,"MW";"  =  ";
250 PRINT#3,USING D$;WTD;:PRINT#3,"  dBm":PRINT#3,
270 PRINT#3,"Path Loss          D,M             D,FT            D,MI"
280 FOR A=30 TO 115 STEP 5
290 X=A+31.13-(20/B)*LOG(F)
300 D=10^(X/20)
310 DF=D*3.28
320 DM=D/1609.756
340 PRINT#3,USING I$;A,D,DF,DM
350 NEXT A
360 INPUT Q$:IF Q$<>"" THEN 380
370 CLS:GOTO 140
380 STOP