[GreenKeys] Powering a Model 15 currentl loop from a 5VDC 250mA power supply - theory

[John Nagle]

      I've been doing some design work on a 120VDC 60mA current loop supply
that only needs a 5VDC 250mA power source.  Right now, this is just a
proof of concept LTSpice simulation.

      The basic concept is that during SPACE periods, a tiny switching
power supply charges up a 1uF capacitor to 120VDC.  During MARK periods,
the capacitor is discharged into the output.  There's also a 3.3V supply
from a linear regulator fed into the output to sustain 60mA during long
MARK periods.  You only need 120VDC for about 2ms after the SPACE to
MARK transition.  The waveform coming out, driving a 55 ohm 4H Teletype
model 15 selector magnet, looks acceptable in simulation.

      This is the way you'd do it if you were designing a Teletype driving
circuit today.  This would be a tiny unit; all the parts are small surface
mount devices, even the transformer.  The whole thing could be integrated
with a microprocessor and driven from a USB port, without any other power
source.

      All that SMT work for a one-off probably isn't worth the trouble, though.
Modern switching power supply parts tend to be surface-mount only; doing
this with through-hole components requires a more retro design.

      The model shows it running from a 4.75V supply because that's the
minimum voltage a USB port must supply.  Max current drawn was 240mA.
Average is about 150mA.  The design is good for up to a 100-speed Teletype;
the capacitor charging takes almost exactly one bit time at 75 baud.

      LTspice model below.

				John Nagle

* D:\projects\teletype\switchingpower\flashsupply5a.asc
L1 Vcc N008 17µ Ipk=0.5 Rser=2.1
L2 0 N005 247µ Rser=0.7
V1 Vcc 0 4.75 Rser=5
D1 N005 Pulse120V D
C2 Pulse120V 0 1µF
R1 Vcc N007 100K
C1 Vcc 0 22µf
V2 serialin 0 PULSE(0 5 5ms 100us 100us 13.2ms 26.6ms 99)
XU1 N007 serialin Vcc N008 MP_01 Vcc 0 LT3484-1
R2 N001 N002 500
A1 serialin 0 0 0 0 N001 0 0 BUF Vhigh=5
L3 Selector 0 4H Rser=55 Rpar=10000
S1 N003 Selector N002 0 hvopto
D3 Pulse120V N003 D
D4 Continuous3.3V N003 D
C3 Selector N006 1000pf
R3 N006 0 100
XU2 MP_07 N004 Continuous3.3V Vcc Vcc LT3080
C4 Vcc 0 1µf
C5 Continuous3.3V 0 2.2µf
R4 N004 0 330K
.model D D
.lib D:\Program Files\LTC\LTspiceIV\lib\cmp\standard.dio
K1 L1 L2 0.98
.tran 60m startup
* 60mA Teletype power supply design test.\nPRELIMINARY\nJ. Nagle 
(nagle at animats.com)\nMay 2009
* Pulse PA1546NL
* Simulated ideal optoisolator
.model hvopto SW(Ron=4.25  Roff=1Meg  Vt=2.0)
.lib LT3080.sub
.lib LT3484-1.sub
.backanno
.end